首页 > 分享 > [宏指南] 从入门到精通，授人以鱼不如授人以渔 178

[宏指南] 从入门到精通，授人以鱼不如授人以渔 178

萌宠菠菠乐园
2024-08-23 23:45

*怀旧服宏：补充技能的运用，还是和正式服一样追求多功能智能化，精益求精的语法
*基础内容一定要先看正式服主贴，怀旧服和和正式服语法完全一样，怀旧服杂事比较多，不像正式服模板化规则化，像蛮荒大地建立规则之初的样子，会有很多注释和机制的讲解，繁琐的细节为简单粗暴的怀旧服带来了深度，掌握这些信息并处理好就是优势，我在此共享信息并希望得到反馈
*习惯是根据实战来优化，实战是规则下的实践，规则确立后续的发展，宏的发展基于规则，文中充斥我的运用“私货”，于规则之下最优解大同小异

怀旧服一些机制细节额外说明

*和正式服区别
正式服：施放打击技能(近战技能)会选择目标>同时自动攻击>同时施放技能(例如/startattack写在技能前面一样效果)

怀旧服：施放打击技能不会选择目标，只有在有资源施放时才会自动攻击>同时施放技能
怀旧服要注意宏的打击技能前需要加入/startattack，有无资源施放都会自动攻击

*怀旧服没有焦点

*怀旧服的GCD是固定的1.5秒，贼猫是1秒，无论如何都无法降低固定GCD；比如牧师的3T1效果快速治疗是1.4秒，法师的职业饰品思维加速1级寒冰剑是0.75秒术但他们的GCD还是1.5秒

*和正式服相同
普攻和技能同时施放，普攻在技能前生效，也可能是怀旧服200毫秒反馈判定造成和正式服相同的假象

怀旧服用的是7.0修订版的宏命令2.0，怀旧服宏的运作机制，命令词汇和正式服是一样的

*起手技能一般需要同时绑定起立，下坐骑命令(经典服需要，TBC开始不需要了)
起立(坐下情况放技能第一次是起立，绑定这个命令按第一次就能放出技能)
/stand
下坐骑(骑马状态需要先下坐骑才能施放技能，绑定这个命令按第一次是下马)
/dismount

*小德变形普攻CD会按百分比延续，不会重新计时

*战斗中换武器会有1.5秒GCD(贼猫为1秒)；换武器会重新计时普攻CD

*招架使你本次近战攻击总量间隔降低40%(剩余不足40%会立刻普攻，怪物也是)，可以理解为1%招架=1%闪避+0.4%攻速X怪物数量，战骑T战斗贼招架收益最大

*1.贼猫改变当前目标会丢豆，取消目标不选择新目标会保留。2.不改变目标鼠标指向友方施放技能不会丢豆，鼠标指向非当前敌方施放技能会丢豆

*圣骑士伤害圣印会触发击中时XX的附魔

*猎法术DK怀旧服在协助攻击命令出来之前，宠物设为被动才能更好的控制宠物不让其做多余的行为，仅主攻技能绑定宠物攻击，其他技能不要过多绑定导致来回乱跑

*法术技能添加/startattack自动攻击除选择目标外还可以偷一棍子

*一个完美的治疗技能宏命令他应该具备所有的判定功能，大部分基础治疗技能宏应该这样写；和正式服区别在没有组合键焦点
优先级按顺序：[mod,@player]组合键自己>[@mouseover,help,nodead]鼠标指向存活友方>[help]目标友方>[@targettarget,help,nodead]目标的目标存活友方>[]无条件施放
/施放 [mod,@player][@mouseover,help,nodead][help][@targettarget,help,nodead][]快速治疗(等级 4)

*复合职业主治疗天赋偶尔或者是PVP情况会打一点输出，在不丢失友方目标/不频繁来回切目标的情况下做到，原理同上
优先级按顺序：[@mouseover,harm,nodead]鼠标指向存活敌方>[harm]目标敌方>[@targettarget,harm,nodead]目标的目标存活敌方>[]无条件施放
/施放 [@mouseover,harm,nodead][harm][@targettarget,harm,nodead][]惩击

*满级1W经验=6G，奥山交牌子=5G

*食物推荐奥特兰克魔法点心30秒双回4410，回血比其他食物高一个档次
*关于回蓝用续航克所有不狂暴的BOSS战斗：黑暗符文800血换1200蓝(同恶魔符文但能交易)，强效昏睡药水12秒回2200血蓝(可能会被队友秒驱)，特效法力药水1800蓝
*一些常备的BUFF：
持续类：龙头，厄运，开花
武器类：磨刀石法力油
药剂类：合剂，赞扎之X，属性药剂
药水类：有限无敌药水，活力行动药水
道具类：工程炸弹，安戈洛水晶

*怀旧服没有快照机制，即你的属性改变不会对已经发射在弹道中还未命中的技能和已经命中的DOT有动态加成

*各种工程魔法反射器对已经发射在弹道中的技能无效

*盗贼猫德能量每2秒恢复20，同步于服务器时间轴，监控这个时序避免溢出和更好的爆发，对于储存能量防止溢出和PVP环境很重要

*吃喝恢复每2秒产生一次，同步于服务器时间轴，监控这个时序实现走喝

*停止施法5秒后开始计时每2秒一次精神回蓝

*术士骑士职业坐骑并非只要100蓝，还要加上后续5秒内每2秒一次共2次精神回蓝，术士骑士精神回蓝公式为“精神/4+8”，以T1毕业200左右精神计算为每2秒58点法力，加上坐骑本身的100需要216点法力，在户外活动(包括安其拉内拿到瞬发虫子以前)频频上下坐骑的过程中损失不容小觑，推荐不要用职业坐骑！

*怀旧服有很多饰品因需要频繁更换(特别是PVP光工程学就常驻5个)，做宏时把常驻的饰品放在14位即第二个饰品位方便配合技能绑定宏使用，经常更换的饰品留给13位用另一个饰品宏使用(内文有)，因为更换饰品默认的是替换13位第一个饰品，常驻饰品放14位避免经常更换饰品发生冲突，和正式服仅1个主动+被动饰品习惯做13位第一个饰品位宏有所不同

*目标数据接收距离怀旧服是60码，正式服100码(正式服小战场是无限制，比如伐木能看到矿洞)，距离内才能收到目标的战斗日志信息，影响你的能见度，黑名单插件，潜行通报插件，“/目标 XX”找目标宏
*“精制望远镜”能拉近很多距离让你收到距离外的信息和视野，比如对黑上门用望远镜才可以目标杰德检查刷新，怀旧服的小战场伐木看铁看矿洞的人数也有效

*攻击性或攻击属性饰品触发同类效果饰品20秒GCD，生存属性和功能性饰品没有GCD

*战士的顺批是主目标附近5码另一个最近的目标，BOSS(红龙，奈法，黑龙)的顺劈是对正前方180°全部目标施放并且影响目标附近8-10码没有被顺批的目标，正常打龙类BOSS站位是近战在侧面，如果有人站在正面和侧面的中间这时中顺劈就会打到旁边侧面8码内的近战(机制是这样但数值可能有差)

小德(攻略了德你就攻略了除人宠合一外的全部)

*小德变形普攻CD会按百分比延续，不会重新计时
*仅猫德和贼用能量的2个职业是1秒GCD，其他职业均为1.5秒
*1.贼猫改变当前目标会丢豆，取消目标不选择新目标会保留。2.不改变目标鼠标指向友方施放技能不会丢豆，鼠标指向非当前敌方施放技能会丢豆
*熊猫切换变形同时换武器，变形本身就有GCD和换武器的GCD重叠，换武器的影响只剩重置普攻CD
*LM战士T和熊T要注意盾猛槌击等T的主要技能绑定“/cancelaura 拯救祝福”和“/cancelaura 强效拯救祝福”，避免团队刷BUFF忘记点掉发生悲剧

小德全形态精灵之火，自动取消旅行形态
#showtooltip
/startattack
/cancelform [form:2/4]
/施放 [noform]精灵之火;精灵之火(野性)

我习惯加入指向，以后的内容从满足所有需求的角度去精简
#showtooltip
/startattack
/cancelform [form:2/4]
/施放 [noform,@mouseover,harm,nodead][noform]精灵之火;[@mouseover,harm,nodead][]精灵之火(野性)

*关于精简：不损失功能的情况下最大的简化字符
[noform]没形态即人形态，比较[form:1/3]熊猫野性精灵之火要节约2字符
[noform:1]不在形态1判定，比较[form:2/3/4]形态234判定要节约2个字符

*如果你有鼠标指向要求的话像主贴正式服的宏加入鼠标判定
*如果你只要基础功能的简化宏也可以自行添加或取消这些额外的判定，以后的内容请自行加减，多个版本不一一举例，选最多功能，智能化，最精简的语法为初衷的版本

*技能整合宏，精简宏的数量，节约宏栏位
一般用于不同形态下才能使用的不同的需要做宏添加判定的技能

例如爪击or挥击因为需要用到/startattack自动攻击而做了宏，这样会占用2个栏位，把他们整合在一起就只有一个栏位
(自动攻击注释：用近战技能会自动选目标，没资源的时候也会选目标，只在放出来的时候才会开启自动攻击，特别是用怒气职业建议常用技能添加自动攻击，以便无怒气施放技能的时候也会开启自动攻击平砍)
#showtooltip
/startattack
/施放 [form:3]爪击;挥击

进阶：为了立马击杀掉萨满的图腾，做了瞬发技能的指向宏，当你鼠标划过去就瞬间秒掉了图腾，从而节约选定的操作，这种简化在德的技能上尤其明显，比如战士在旋风斩或顺批的时候旁边目标闪避了，你可以划过去用一键切换姿态带指向功能的压制宏对闪避目标压制
(猫贼会丢豆子建议手动，下面只改了熊挥击)
#showtooltip
/startattack
/施放 [form:3]爪击;[@mouseover,harm,nodead][]挥击

/startattack自动攻击命令的使用：用近战技能会自动选择最近的目标(跟TAB一样，仅选择)，近战技能施放成功的同时会开启自动攻击。建议怒气职业常用技能添加自动攻击，以便无怒气施放技能的时候也会开启自动攻击平砍。潜行技能在找面向时会多次尝试施放，不要添加自动攻击避免破潜行

小德取消其他形态同时变形>潜行>技能，组合键取消潜行
#showtooltip
/cancelaura [mod]潜行
/cancelform [noform:3]
/施放 [noform:3]猎豹形态;[nostealth]潜行;毁灭

小德取消其他形态同时变形同时潜行>技能，组合键取消潜行
#showtooltip
/cancelaura [mod]潜行
/cancelform [noform:3]
/施放 [noform:3]猎豹形态
/施放 [nostealth]潜行;毁灭

整合有GCD和无GCD技能一键施放简化操作
无GCD技能：部分打断，冲锋拦截，变形姿态，影遁贼德潜行
有GCD和无GCD技能的组合一键完成简化操作；
比如切之态同时冲锋并自动判定战斗中切狂暴拦截，防御姿态同时盾击，小德变形同时潜行，这些操作都只需要一键

德整合步进1：潜行>潜行技能>普通技能，组合键取消潜行，爪机和挥击整合
#showtooltip
/cancelaura [mod]潜行
/施放 [form:3,nocombat,nostealth]潜行;[form:3,stealth]毁灭;[form:3]爪击;[@mouseover,harm,nodead][]挥击

德整合步进2(四键)：取消其他形态同时变形>潜行>潜行技能>普通技能，组合键取消潜行
#showtooltip
/cancelaura [mod]潜行
/cancelform [noform:3]
/施放 [noform:3]猎豹形态;[nocombat,nostealth]潜行;[stealth]毁灭;撕碎

德整合完整版(三键).取消其他形态同时变形同时潜行>潜行技能>普通技能，ctrl或alt取消潜行
*变形作为起手技能加入额外的下坐骑，起立
*增加shift覆盖变形；加入此开关把宏当作常规变形减少重复功能节省键位，点了激怒覆盖变形刷能量；另秒解定身减速
*增加非潜行自动攻击“/startattack [nostealth]”在不影响潜行起手技能的情况让组合宏里的常规技能转目标同时普攻，不要依赖近战技能施放成功才会开启的自动攻击
*熊猫切换变形同时换武器，变形本身就有GCD和换武器的GCD重叠，换武器的影响只剩重置普攻CD
#showtooltip
/stand
/dismount
/cancelaura [mod]潜行
/cancelform [mod:shift][noform:3]
/施放 [noform:3]猎豹形态
/startattack [nostealth]
/施放 [nomod,nocombat,nostealth]潜行;[stealth]毁灭;撕碎
/eq 猫武器

一键冲锋(德)：取消其他形态同时变熊同时冲锋(自动攻击在变形之后，如果没有CD可以增加怒气)
*变形作为起手技能加入额外的下坐骑，起立
*增加组合键覆盖变形；加入此开关把宏当作常规变形减少重复功能节省键位，避免点了激怒天赋变形有资源导致同时误放技能；另秒解定身减速
*熊猫切换变形同时换武器，变形本身就有GCD和换武器的GCD重叠，换武器的影响只剩重置普攻CD
#showtooltip [@mouseover,harm,nodead][]野性冲锋
/stand
/dismount
/cancelform [mod][noform:1]
/施放 [noform:1]巨熊形态
/startattack
/施放 [@mouseover,harm,nodead][]野性冲锋
/eq 熊武器

一键重击：取消其他形态同时变熊同时重击(自动攻击在变形之后，如果没有CD可以增加怒气)
*变形作为起手技能加入额外的下坐骑，起立
*增加组合键覆盖变形；加入此开关把宏当作常规变形减少重复功能节省键位，避免点了激怒天赋变形有资源导致同时误放技能；另秒解定身减速
*熊猫切换变形同时换武器，变形本身就有GCD和换武器的GCD重叠，换武器的影响只剩重置普攻CD
#showtooltip [@mouseover,harm,nodead][]重击
/stand
/dismount
/cancelform [mod][noform:1]
/施放 [noform:1]巨熊形态
/startattack
/施放 [@mouseover,harm,nodead][]重击
/eq 熊武器

嘲讽版，重击，冲锋，都是反应技能必备一气呵成
#showtooltip [@mouseover,harm,nodead][]低吼
/stand
/dismount
/cancelform [mod][noform:1]
/施放 [noform:1]巨熊形态
/startattack
/施放 [@mouseover,harm,nodead][]低吼
/eq 熊武器

全形态精灵之火+一键嘲讽整合；全形态精灵之火，自动取消旅行形态；按组合键变形嘲讽同时精灵之火
*这2个技能都是常用的需要便捷的键位，是有用的但不是必须的，认为嘲讽应享有最高优先级不该用组合键施放；是一个复杂的宏，可当作形态条件举例
#showtooltip
/stand
/dismount
/startattack
/cancelform [mod,noform:1][form:2/4]
/施放 [mod,noform:1]巨熊形态
/施放 [mod,@mouseover,harm,nodead][mod]低吼
/施放 [noform,@mouseover,harm,nodead][noform]精灵之火;[@mouseover,harm,nodead][]精灵之火(野性)

全形态精灵之火+一键战复整合；全形态精灵之火，自动取消旅行形态；按组合键取消形态鼠标瞄点施放复活(对释放尸体用或看CD)>指向友方死亡取消形态复活>目标友方死亡取消形态复活
*精灵之火是个常用技能，绑定复活方便使用；是一个复杂的宏，可当作形态条件举例
#showtooltip
/stand
/dismount
/startattack
/cancelform [mod] [@mouseover,help,dead] [help,dead][form:2/4]
/施放 [mod] [@mouseover,help,dead] [help,dead]复生;[noform,@mouseover,harm,nodead][noform]精灵之火;[@mouseover,harm,nodead][]精灵之火(野性)

组合键ctrl战复(对释放尸体用或看CD)>指向死亡复活>目标死亡复活；其他组合键解咒自己>指向友方>目标友方>目标的目标友方>无条件施放
#showtooltip
/cancelform
/施放 [mod:ctrl] [@mouseover,help,dead] [help,dead]复生;[mod,@player][@mouseover,help,nodead][help][@targettarget,help,nodead][]解除诅咒

牧德骑萨治疗技能通用格式，小德绑定取消形态
组合键自己>指向友方>目标友方>目标的目标友方>默认施放
#showtooltip
/cancelform
/施放 [mod,@player][@mouseover,help,nodead][help][@targettarget,help,nodead][]愈合

按shift迅捷触，按ctrl对自己迅捷触>鼠标指向友方>目标友方>目标的目标友方>无条件施放
*适用于回春，愈合，解毒等一切治疗技能；包括德骑萨的治疗技能，自然迅捷改心灵专注和神恩术
#showtooltip
/cancelform
/施放 [mod:ctrl/shift]自然迅捷
/施放 [mod:ctrl,@player][@mouseover,help,nodead][help][@targettarget,help,nodead][]治疗之触

指向休眠>目标休眠；组合键安抚
#showtooltip
/cancelform
/施放 [mod,@mouseover,harm,nodead][mod]安抚动物;[@mouseover,harm,nodead][]休眠

一键飓风，按组合键鼠标点击施放，取消变形
#showtooltip
/startattack
/cancelform
/施放 [mod] [@cursor] 飓风

一键追踪，非猫形态取消变形同时变猫，猫形态施放追踪
#showtooltip 追踪人型生物
/cancelform [noform:3]
/施放 [noform:3]猎豹形态;追踪人型生物

吃药四合一；添加德功能，取消变形同时吃药同时变形，组合键吃不同的药，没有占用GCD才能同时无缝变形
#showtooltip
/cancelform
/施放 [mod:atl]自由行动药剂;[mod:ctrl]有限无敌药水;[mod]XX药水;强效石盾药水
/施放巨熊形态

保护，激活，战复等需要密语提醒的技能添加
/脚本 local n=UnitName("target");SendChatMessage(string.format("这里填密语内容",n ),"whisper",nil,n)

盗贼

*仅猫德和贼用能量的2个职业是1秒GCD，其他职业均为1.5秒
*1.贼猫改变当前目标会丢豆，取消目标不选择新目标会保留。2.不改变目标鼠标指向友方施放技能不会丢豆，鼠标指向非当前敌方施放技能会丢豆
*战斗中换武器会有1秒GCD(贼猫GCD是1秒，其他职业GCD是1.5秒)，重新计时普攻CD(起手技能第一下普攻已随技能打出去，普攻进入CD同时切换武器对后续普攻没有造成损失)
*剑锤贼可潜行同时用宏切换匕首方便使用伏击背刺，非主手限定的武器可以和副手用宏无障碍互换，主手限定的武器必须用包里的武器来替换

战斗贼脱战潜行+换匕首，潜行偷窃+伏击或偷袭，战斗切割或背刺+换剑锤
*潜行作为起手技能加入额外的下坐骑，起立
*主副互换如果主武器限定主手，就不能和副武器互换，要额外准备一把匕首
潜伏切三键版
潜行+换匕首>偷窃+伏击>切割+换剑锤；组合键取消潜行
#showtooltip [nocombat,nostealth]潜行;[stealth]伏击;切割
/stand
/dismount
/cancelaura [mod]潜行
/施放搜索
/stopcasting
/施放 [nocombat,nostealth]潜行;[stealth]伏击;切割
/eq [stealth]匕首名字
/eq [nostealth]剑锤名字

潜伏二键版
潜行+换匕首>偷窃+伏击+换剑锤；组合键取消潜行
#showtooltip [nocombat,nostealth]潜行;伏击
/stand
/dismount
/cancelaura [mod]潜行
/施放搜索
/stopcasting
/施放 [nocombat,nostealth]潜行;伏击
/eq [stealth]匕首名字
/eq [nostealth]剑锤名字

潜伏背刺版；换匕首，弩射击(弩射击靠前不会占用潜行)
#showtooltip [nocombat,nostealth]潜行;[stealth]伏击;背刺
/stand
/dismount
/cancelaura [mod]潜行
/施放搜索
/施放弩射击
/stopcasting
/startattack [nostealth]
/施放 [nocombat,nostealth]潜行;[stealth]伏击;背刺
/eq 匕首名字

潜袭邪击版；潜行匕首显形剑锤，还击优先，弩射击(弩射击靠前不会占用潜行)
#showtooltip [nocombat,nostealth]潜行;[stealth]偷袭;邪恶攻击
/stand
/dismount
/cancelaura [mod]潜行
/施放搜索
/施放弩射击
/stopcasting
/startattack [nostealth]
/施放 [nocombat,nostealth]潜行;[stealth]偷袭;还击
/施放邪恶攻击
/eq [stealth]匕首名字
/eq [nostealth]剑锤名字

盗贼还击+邪恶+投掷(弓弩枪)+换武器
换武器放在技能前需要按2次影响手感，为了避免第一次伤害由匕首造成所以换武器由上面的潜行宏完成，这里加入作为检查保险
#showtooltip 邪恶攻击
/startattack
/施放还击
/施放邪恶攻击
/施放投掷
/eq 剑锤名字

凿击，致盲，忏悔，诸如此类技能的偷刀宏(放技能时你的普攻没CD就能偷一刀，原理是伤害在效果之前产生不会打破控制。此类技能施放成功本就会停止攻击，加上/stopattack停止攻击防止因连按再次自动攻击，在下次普攻CD就绪之前都不会因连按而攻击)
#showtooltip
/startattack
/stopattack
/施放 [@mouseover,harm,nodead][]致盲

开锁，自动选择多个指定锁(自行添加)，同一种复数的锁需要先拾取才能开后面的，同时出现开锁指针
/施放开锁
/use 瑟银宝箱
/use 恒金宝箱
/use 重垃圾箱
/施放开锁

开指定锁，按第一次开锁，按第二次拾取，只能填一种锁名字，包里没有指定锁则出现开锁指针
#showtooltip 开锁
/use 重垃圾箱
/run for i=1,GetNumLootItems()do if GetLootSlotInfo(i) then LootSlot(i)end;end
/施放开锁
/use 重垃圾箱

一键偷取你屏幕中间正对着的目标，鼠标指向优先
#showtooltip
/cleartarget
/targetenemy
/cast [@mouseover,harm,nodead][]搜索

一键扰乱，组合键鼠标选择位置
#showtooltip
/施放 [mod] [@cursor] 扰乱

不打断死亡射线无缝接剔骨(通常用于秒法师防止闪现)
/施放 [nochanneling:侏儒死亡射线]剔骨
整合版
/施放 [mod]侏儒死亡射线;[nochanneling:侏儒死亡射线]剔骨

上毒药四合一，左键主手右键副手
#showtooltip
/施放 [mod:alt]致命毒药 V; [mod:ctrl]麻痹毒药 III;[mod]致残毒药 II;速效毒药 VI
/use [button:1]16; [button:2]17

猎人

*假死可以吃喝，战斗中回蓝首选，对配装影响深远，很重要！
*猎人的近战攻击和远程攻击CD是独立的，可以用宏绑定雄鹰多重方便的切换目标的同时放技能保持攻击对近身和远程敌人实现输出最大化
*假死同时宠物停止攻击行为(跟随或改被动)才能使本体脱战，然后放陷阱同时影遁吃喝
*添加!防止复按取消自动射击，所有包含自动射击的宏都应加!
*自动射击也会随着技能施放自动打开，包括超出距离未能施放成功的近战技能，技能必须是就绪能施放状态才会自动打开，如下“/施放 !自动射击”
*远程技能可绑定猛禽一击，要加在自动攻击命令前面，在第一次近战攻击生效
*瞄准射击需要3秒，自动射击有0.5秒读条，所以武器越接近3.5秒普攻就绪滞留损失的时间越少，就能打出无损循环的极限输出
*玩猎人术士不想被下指令的吵到一定要关闭宠物表情音效，不会影响战斗音效
*尝试施放近战技能和/startattack自动攻击命令会打断瞄准射击影藏读条；施放任何技能会打断引导

TBC更新
*TBC版本自动攻击“/startattack”整合了自动射击，会根据距离自动切换近战和远程攻击了，可以取消宏里的“/施放 !自动射击”这个命令了

指向多重，自动射击，宝宝攻击>目标多重，自动射击，宝宝攻击；绑定猛禽
*技能没好也会自动射击，鼠标指向点图腾，近战施放猛禽，猎人远近攻击不共CD，保持指向对远处目标攻击同时对近身目标近战攻击，利用这个命令最大化资源节省切目标操作量；可如法炮制其他技能，控宠命令不宜过多使用导致其跑在路上
#showtooltip [@mouseover,harm,nodead][]多重射击
/施放猛禽一击
/startattack
/petattack [@mouseover,harm,nodead];
/施放 [@mouseover,harm,nodead][]!自动射击
/施放 [@mouseover,harm,nodead][]多重射击

*多重和奥射应该加入1级组合键开关，1级多重用于不能假死回蓝的单目标长时间战斗续航(3目标建议打满级100蓝换360奥术伤害)；1级奥射用于保持单刷风筝不脱战，PVP保持不脱战，秒图腾
*唯一远程宠物风蛇跟随身边闪电震击(20码内才会施放)，唯一BUFF宠物座狼跟随身边狼嚎配合瞄准射击增伤
*“/petattack [@mouseover,harm,nodead];”这个宠物攻击命令有指向功能，风蛇开启自动震击会第一时间施放，宠物普攻优先指向目标秒图腾转火更便捷
*“/petfollow”宠物跟随会跟随在身边只放震击技能
#showtooltip [mod]多重射击(等级 1);[@mouseover,harm,nodead][]多重射击
/施放猛禽一击
/startattack
/petattack [@mouseover,harm,nodead];
/petfollow
/施放 [@mouseover,harm,nodead][]!自动射击
/施放 [mod,@mouseover,harm,nodead][mod]多重射击(等级 1);[@mouseover,harm,nodead][]多重射击
/施放狂怒之嚎

*猎人的近战和射击不是共CD，就是说猎人的最高DPS是保持远近攻击的CD，添加这个命令的宏不用来回切目标节省操作量，或者临时射点什么，但是谁会去记这些奇怪的条件还熟练运用呢？
/施放 [@mouseover,harm,nodead][]!自动射击

胁迫前面加停止施法主要是打断瞄准射击，和反制沉默不同的是有一定几率需要连按2次可能是作用于宝宝需要反馈的原因，但如果停止施法不加到胁迫前面的话无论如何都需要按2次
#showtooltip
/stopcasting
/施放胁迫
/施放猛禽一击
/startattack
/petattack [@mouseover,harm,nodead];
/施放 [@mouseover,harm,nodead][]!自动射击

驱散射击，自动打断引导和瞄准，驱散会自动停止包括宝宝的攻击
#showtooltip [@mouseover,harm,nodead][]驱散射击
/施放猛禽一击
/startattack
/施放 [@mouseover,harm,nodead][]驱散射击

宁神射击，自动打断引导和瞄准
#showtooltip [@mouseover,harm,nodead][]宁神射击
/施放猛禽一击
/startattack
/petattack [@mouseover,harm,nodead];
/施放 [@mouseover,harm,nodead][]!自动射击
/施放 [@mouseover,harm,nodead][]宁神射击

逃脱会停止攻击我们让他不停止；惯例添加攻击射击猛禽老三样
#showtooltip [@mouseover,harm,nodead][]逃脱
/施放 [@mouseover,harm,nodead][]!自动射击
/施放 [@mouseover,harm,nodead][]逃脱
/施放猛禽一击
/startattack

猎人守护整合，主要是分配三个组合键，根据不同类型自行组合(!防止取消)
#showtooltip
/startattack
/施放 [mod:ctrl]!野兽守护;[mod]!豹群守护;!猎豹守护

#showtooltip
/startattack
/施放 [mod:ctrl]!野性守护;[mod]!灵猴守护;!雄鹰守护

猎人一键召唤喂养，所有宠物类型和相应食物
#showtooltip
/stand
/dismount
/施放 [pet]喂养宠物;召唤宠物
/use [pet:豹/狼/迅猛龙/猫头鹰]烤鹌鹑;[pet:蝙蝠]风干的香蕉;[pet:熊/猩猩/野猪/风蛇]魔法甜面包

死了复活，没有尸体按组合键复活>活着解散>没有召唤；跟随保持10码解散范围
#showtooltip
/petfollow
/startattack
/施放 [mod] [@pet,dead] 复活宠物;[pet]解散野兽;召唤宠物

四合一究极宠物宏(前两个宏的整合)：死了复活，没有尸体按atl复活>按组合键喂养>活着解散>没有召唤
#showtooltip
/stand
/dismount
/petfollow
/startattack
/施放 [mod:alt] [@pet,dead] 复活宠物;[mod]喂养宠物;[pet]解散野兽;召唤宠物
/施放 [pet:豹/狼/迅猛龙/猫头鹰]烤鹌鹑;[pet:蝙蝠]风干的香蕉;[pet:熊/猩猩/野猪/风蛇]魔法甜面包

治疗宠物，组合键低级治疗解DEBUFF；防止中断引导
#showtooltip 治疗宠物
/startattack
/施放 [mod]治疗宠物(等级 1);[nochanneling:治疗宠物]治疗宠物

天眼查
#showtooltip
/stand
/dismount
/施放 [@cursor] !鹰眼术

战斗假死同时吃喝>影遁陷阱，脱战影遁陷阱，组合键其他影遁陷阱
*假死同时宠物停止攻击行为(跟随或改被动)才能使本体脱战，然后放陷阱同时影遁吃喝
#showtooltip
/petfollow
/施放 [combat]假死
/施放 [mod:alt]冰霜陷阱;[mod:ctrl]献祭陷阱;[mod]爆炸陷阱;冰冻陷阱
/施放魔法甜面包
/施放魔法晶水
/施放 !影遁
/施放 !潜伏
*注意：1.必须加入/petfollow宠物跟随，假死同时命令宠物跟随能起到脱战效果，宠物一直攻击的话主人假死就不能脱战
2.假死和陷阱不能写在一行是因为主人脱战宠物依然在战斗，所以显示会以整体为准，但陷阱的施放只判定主人

战士境界武器大师，姿态精通

*换武器会重新计时普攻CD
*战斗中换武器会有1.5秒GCD
*切换武器的代价：基于以上两点不存在双持狂暴出闪避切武器换双手打压制的操作，只有双手狂暴才可以这样玩

*战士战斗姿态换剑盾打断
优势是6秒高质量打断，不被迫切姿态保留超过25点怒气和节奏
代价是重置普攻CD，和1.5秒GCD对操作手速和技能长短判断要求较高
和切狂暴拳击是秒断4秒各有优劣
我提供多个版本，目的是整合在一个键位，且能无虑施放

*LM战士T和熊T要注意盾猛槌击等T的主要技能绑定“/cancelaura 拯救祝福”和“/cancelaura 强效拯救祝福”，避免团队刷BUFF忘记点掉发生悲剧

*关于压制1.敌人躲闪触发压制激活5秒使用时间，这期间换新目标会作废即切回去躲闪目标不能使用，仅取消当前目标没选新目标又选回躲闪目标依然可以使用；2.AOE技能横扫顺批旋风斩非当前目标闪避首选指向施法去尝试施放，避免切换目标点错失去机会增加操作量丢失主目标的普攻等问题(指向施放并非选择目标施放，尝试一个错误的目标不会失去使用机会)

一键冲锋or拦截，1.姿态图标版无法监视技能图标CD和距离：切战斗姿态冲锋>战斗中切狂暴拦截；按组合键强制拦截
这个版本显示的姿态图标，切换姿态后才显示技能，因为同时施放的缘故，基本看不到显示技能的情况，这样就失去了监视技能图标CD和超出距离变红的功能
#showtooltip
/施放 [mod][combat]狂暴姿态;战斗姿态
/startattack
/施放 [mod][combat,@mouseover,harm,nodead][combat]拦截;[@mouseover,harm,nodead][]冲锋

一键冲锋or拦截，2.技能图标版监视技能CD和距离：功能同上，区别在有图标距离显示，起手技能应添加起立下马命令
这个版本脱战显示冲锋，战斗拦截，指向和目标都有距离判定
#showtooltip [mod][combat,@mouseover,harm,nodead][combat]拦截;[@mouseover,harm,nodead][]冲锋
/stand
/dismount
/施放 [mod][combat]狂暴姿态;战斗姿态
/startattack
/施放 [mod][combat,@mouseover,harm,nodead][combat]拦截;[@mouseover,harm,nodead][]冲锋

双吼，节约键位
#showtooltip
/startattack
/施放 [mod]战斗怒吼;挫志怒吼

战神：顾名思义，三合一自动切姿态换武器天神下凡
*可以用作一键切换剑盾和防御姿态不会下坐骑，已是剑盾会尝试施放技能下坐骑；这个附属功能是方便坐骑上变得更硬方便冲破障碍赶路
#showtooltip [mod:alt]鲁莽;[mod]反击风暴;盾墙
/施放 [mod:alt]狂暴姿态;[mod]战斗姿态;防御姿态
/eq [mod]双手武器
/eq [nomod]单手武器
/eq [nomod]盾牌名字
/施放 [mod:alt]鲁莽;[mod]反击风暴;盾墙

一键盾击：狂暴切防御，战斗直接盾击
#showtooltip [@mouseover,harm,nodead][]盾击
/施放 [form:3]防御姿态
/startattack
/eq 单手武器
/eq 盾牌名字
/施放血性狂暴
/施放 [@mouseover,harm,nodead][]盾击

一键拳击：切狂暴同时拳击
#showtooltip [@mouseover,harm,nodead][]拳击
/施放狂暴姿态
/startattack
/施放血性狂暴
/施放 [@mouseover,harm,nodead][]拳击

拳盾合一：战斗防御盾击，狂暴拳击
#showtooltip [form:3,@mouseover,harm,nodead][form:3]拳击;[@mouseover,harm,nodead][]盾击
/startattack
/eq [form:1/2]单手武器
/eq [form:1/2]盾牌名字
/施放血性狂暴
/施放 [form:3,@mouseover,harm,nodead][form:3]拳击;[@mouseover,harm,nodead][]盾击

拳盾合一2：防御盾击，战斗切狂暴拳击
*这是我目前在用的版本，主要原因是武器战主要打PVP换武器1.5秒GCD不适合，重置普攻和怒气损失利弊互相抵消，如果是纯PVE考虑用前一个版本6秒断质量更高，但没人会用武器打纯PVE吧
#showtooltip [form:2,@mouseover,harm,nodead][form:2]盾击;[@mouseover,harm,nodead][]拳击
/施放 [form:1]狂暴姿态
/startattack
/eq [form:2]单手武器
/eq [form:2]盾牌名字
/施放血性狂暴
/施放 [form:2,@mouseover,harm,nodead][form:2]盾击;[@mouseover,harm,nodead][]拳击

一键盾猛：默认取消拯救，换盾牌猛击，远距离射击兼开怪
#showtooltip [@mouseover,harm,nodead][]盾牌猛击
/cancelaura 拯救祝福
/cancelaura 强效拯救祝福
/startattack
/eq 单手武器
/eq 盾牌名字
/施放 [@mouseover,harm,nodead][]盾牌猛击
/施放 [@mouseover,harm,nodead][]弩射击

一键缴械：切防御同时缴械
#showtooltip [@mouseover,harm,nodead][]缴械
/施放防御姿态
/startattack
/施放血性狂暴
/施放 [@mouseover,harm,nodead][]缴械

一键旋风：切狂暴同时旋风斩
#showtooltip 旋风斩
/施放狂暴姿态
/eq 双手武器
/startattack
/施放旋风斩

一键压制：战斗直接压制，防御狂暴切武器同时压制
#showtooltip [@mouseover,harm,nodead][]压制
/施放战斗姿态
/eq 双手武器
/startattack
/施放 [@mouseover,harm,nodead][]压制

一键断筋：武器直接断筋，防御切狂暴同时断筋
#showtooltip [@mouseover,harm,nodead][]断筋
/施放 [form:2]狂暴姿态
/startattack
/施放 [@mouseover,harm,nodead][]断筋

一键斩杀：武器直接斩杀，防御切狂暴同时斩杀
#showtooltip [@mouseover,harm,nodead][]斩杀
/施放 [form:2]狂暴姿态
/startattack
/施放 [@mouseover,harm,nodead][]斩杀

一键横扫：切姿态同时血性狂暴同时横扫，战斗姿态怒气=>30只需要按1次，其他姿态需要等待普攻或血性狂暴返还的怒气有延迟，所以需要按2次
#showtooltip 横扫攻击
/施放战斗姿态
/eq 双手武器
/startattack
/施放血性狂暴
/施放横扫攻击

坦克6秒循环，添加格挡、英勇、锁定防御姿态、优先鼠标指向，仇恨全开一键宏，无尽怒气使用
#showtooltip
/施放 [noform:2]防御姿态
/castsequence [@mouseover,harm,nodead][]reset=5/combat 盾牌猛击,复仇,破甲攻击,破甲攻击
/施放盾牌格挡
/施放英勇打击
/startattack

*注意1：战士和熊一样自动攻击加怒气，应该在切换姿态之后才自动攻击增加当前姿态的怒气，保证不易出，也保证变熊或切姿态后当前姿态有额外的怒气
举例：如果你有25点怒气切姿态旋风斩，你也正好普攻没有CD，切换姿态后普攻加了10点怒气，旋风斩用掉25点，这时候你还剩10点，而不是先攻击在随着切姿态浪费掉，在PVE无间断的普攻这个逻辑细节可能没有用，不过PVP经常有打不到人普攻无CD的状态是很有用的，养成良好的逻辑习惯
战德还有很多可以做一键切姿态的技能，缴械，嘲讽，盾墙，惩戒痛击，狂暴之怒，精灵之火，诸如此类等等，如法炮制

*注意2：战士的姿态不会取消，德鲁伊的形态重复按会取消变人，他们涉及姿态或形态的宏有一定差异
比如战士有拳击，缴械这种指定单一姿态施放的技能只需要“/施放 XX姿态”即可，而盾击，断筋，斩杀这种双姿态都能施放的技能要加入“/施放 [form：X]XX姿态”来判定，比如你在防御姿态去按断筋就会切到指定的战斗或狂暴之态施放
*德鲁伊的技能都是单形态施放，不像战士有双姿态能施放的技能，比如要变熊冲锋第一行先取消别的形态“/cancelform [form:2/3/4]”取消234形态，第二行“/施放 [noform:1]巨熊形态”变熊，其中[noform:1]防止重复按键取消形态

布甲魔杖射击指向目标，宝宝攻击指向目标>射击目标，宝宝攻击目标
#showtooltip
/startattack
/petattack [@mouseover,harm,nodead];
/施放 [@mouseover,harm,nodead][]!射击

牧师

友方优先指向驱散复活同时解除形态，组合键驱自己或复活(对释放尸体用)；敌方优先指向沉默
#showtooltip
/stopcasting [@mouseover,harm] [harm]
/cancelform [mod] [@mouseover,help] [help]
/施放 [mod:ctrl] [@mouseover,help,dead] [help,dead]复活术;[mod,@player] [@mouseover,help] [help]驱除疾病;[@mouseover,harm,nodead][]沉默
*注意：非暗牧沉默可以改别的技能，如果是改成读条技能就要去掉指向和目标是敌方就停止施法/stopcasting [@mouseover,harm] [harm]，否则会反复断条冲突；非暗牧取消形态这一条也没有用了去掉/cancelform [mod] [@mouseover,help] [help]

优先指向驱散，组合键驱自己
#showtooltip
/施放 [mod,@player][@mouseover,exists,nodead][]驱散魔法

精神鞭笞不打断引导，组合键同时开启饰品，指向优先
*[nochanneling:技能名字]也适用于奥术飞弹，术士吸取，猎人治疗，死亡射线等所有引导技能或道具，不指定技能名字则是对所有引导技能生效[nochanneling]
#showtooltip [mod]14;[@mouseover,harm,nodead][]精神鞭笞
/use [mod]14
/startattack
/施放 [@mouseover,harm,nodead,nochanneling:精神鞭笞][nochanneling:精神鞭笞]精神鞭笞

加入!防止误触取消形态，取消!在施放暗影形态1.5秒后能直接按下取消形态；按组合键取消形态
*起立同时暗影形态，坐骑上可以取消形态遂取消了下坐骑命令
*如果没有使用插件在坐骑上尝试施放技能是不会自动下坐骑的，所以起手类型技能要时常绑定“/stand”起立，“/dismount”下坐骑，此后文中宏示范均不添加这2个命令，有需要的注意这点自行添加
#showtooltip
/stand
/startattack
/cancelform [mod]
/施放暗影形态

按shift指向1级痛>按shift目标1级痛向>指向满级痛>目标满级痛(1级追杀刷晕或聚怪)；按ctrl同时开启饰品
#showtooltip
/use [mod:ctrl]14
/startattack
/施放 [mod:shift,@mouseover,help,nodead][mod:shift]暗言术：痛(等级 1);[@mouseover,help,nodead][]暗言术：痛

治疗专用不换目标打输出，增加目标的目标额外功能
#showtooltip
/施放 [mod,@mouseover,harm,nodead][mod,harm][mod,@targettarget,harm,nodead]暗言术：痛(等级 1);[@mouseover,harm,nodead][harm][@targettarget,harm,nodead][]暗言术：痛

取消暗影形态读强效治疗术，ctrl/shift开启心灵专注+饰品，ctrl对自己>指向友方>目标友方>目标的目标友方>无条件对自己
*心灵专注一行在饰品一行前，在按组合键时显示心灵专注CD便于监视
*神圣星星，治疗祷言，心灵震爆，一切吃暴击高消耗的技能都可以配合心灵专注
*适用于恢复，盾，快速等一切治疗技能；包括德骑萨的治疗技能，心灵专注改神恩术和自然迅捷
#showtooltip
/cancelaura 暗影形态
/施放 [mod:ctrl/shift]心灵专注
/use [mod:ctrl/shift]14
/施放 [mod:ctrl,@player][@mouseover,help,nodead][help][@targettarget,help,nodead][]强效治疗术

治疗祷言整合心灵专注和低级祷言；按ctrl/shift心灵专注+开启饰品同时治疗祷言，按atl低级治疗祷言
#showtooltip
/cancelaura 暗影形态
/施放 [mod:ctrl/shift]心灵专注
/use [mod:ctrl/shift]14
/施放 [mod:alt]治疗祷言(等级 2);治疗祷言

治疗输出组合包：指向敌方>目标敌方>目标的目标敌方
*非暗夜星辰碎片改成惩击X2，删除防打断nochanneling:星辰碎片
#showtooltip
/castsequence [@mouseover,harm,nodead,nochanneling:星辰碎片][harm,nochanneling:星辰碎片][@targettarget,harm,nodead,nochanneling:星辰碎片][]reset=8 心灵震爆,神圣之火,星辰碎片

心灵震爆等常规技能，组合键同时开启饰品+心灵专注，指向优先
#showtooltip
/施放 [mod]心灵专注
/use [mod]14
/startattack
/施放 [@mouseover,harm,nodead][]心灵震爆

上BUFF优先指向，组合键群体BUFF
#showtooltip
/施放 [mod:ctrl/shift,@mouseover,help,nodead][mod:ctrl/shift]坚韧祷言;[@mouseover,help,nodead][]真言术：韧

神圣新星，ctrl一级，shift心灵专注+饰品同时神圣新星
#showtooltip
/cancelaura 暗影形态
/施放 [mod:shift]心灵专注
/use [mod:shift]14
/施放 [mod:ctrl]神圣新星(等级 1);神圣新星

骑士

组合键ctrl复活(对释放尸体用)>指向死亡复活>目标死亡复活；其他组合键驱散自己>指向友方>目标友方>目标的目标友方>默认施放
#showtooltip
/施放 [mod:ctrl] [@mouseover,help,dead] [help,dead]救赎;[mod,@player][@mouseover,help,nodead][help][@targettarget,help,nodead][]清洁术

忏悔优先指向，打断施法
#showtooltip
/startattack
/stopcasting
/施放 [@mouseover,harm,nodead][]忏悔
*变形/瘫痪类软控制指会被伤害打破的完全失去控制的技能，包括盲闷凿忏羊等，这类技能施放成功会自动停止攻击不需要额外加入命令
*注意瘫痪类道具如手雷不会自动停止攻击

各种祝福组合键小的，直接施放大的，指向优先
*默认大的才15分钟，为什么不丢弃5分钟小的？有时候同职业要上点不一样的就给小的
#showtooltip
/施放 [mod,@mouseover,help,nodead][mod]各种祝福;[@mouseover,help,nodead][]强效各种祝福

按shift神恩术饰品同时圣光术，按ctrl对自己神恩饰品圣光术>鼠标指向友方>目标友方>目标的目标友方>无条件施放
*神恩一行在饰品一行前，在按组合键时显示神恩CD便于监视
*适用于圣闪，驱散，牺牲，自由等一切治疗和辅助技能；包括德骑萨的治疗技能，神恩术改心灵专注和自然迅捷
#showtooltip
/施放 [mod:ctrl/shift]神恩术
/use [mod:ctrl/shift]14
/施放 [mod:ctrl,@player][@mouseover,help,nodead][help][@targettarget,help,nodead][]圣光术

指向敌方>目标敌方>目标的目标敌方>无条件施放
*锤子，制裁，驱邪都可以做成这种格式，方便治疗不换目标输出；不能加入自动攻击命令，该命令会选敌对目标破坏便捷
#showtooltip
/施放 [@mouseover,harm,nodead][harm][@targettarget,harm,nodead][]审判

圣疗术绑定吃蓝，优先指向，组合键对自己
#showtooltip
/施放 [mod,@player][@mouseover,help,nodead][]圣疗术
/施放特效法力药水

保护祝福组合键自己>鼠标指向>目标>无条件施放；加入停止施法打断读条
*圣盾术冰箱需要立即施放的技能都应该加入“/stopcasting”停止施法
#showtooltip
/stopcasting
/施放 [mod,@player][@mouseover,help,nodead][]保护祝福

震击，优先指向；shift神恩+饰品震击，ctrl对自己
#showtooltip
/施放 [mod:ctrl/shift]神恩术
/use [mod:ctrl/shift]14
/施放 [mod:ctrl,@player][@mouseover,exists,nodead][]神圣震击

法师，解诅咒和反制+？

法师

按shift施放1级寒冰(1秒读条减速)>按shift鼠标指向1级>按shift目标1级>指向满级>目标满级；按ctrl开启饰品同时满级寒冰剑
#showtooltip
/use [mod:ctrl]14
/startattack
/施放 [mod:shift,@mouseover,harm,nodead][mod:shift]寒冰箭(等级 1);[@mouseover,harm,nodead][]寒冰箭

我在用的一个变种，组合键1级寒冰剑>直接按满级寒冰剑同时开启饰品
#showtooltip
/use [nomod]14
/startattack
/施放 [mod,@mouseover,harm,nodead][mod]寒冰箭(等级 1);[@mouseover,harm,nodead][]寒冰箭

火球术等常规技能，组合键同时开启饰品，指向优先
#showtooltip
/use [mod]14
/startattack
/施放 [@mouseover,harm,nodead][]火球术

奥术飞弹不打断引导，组合键同时开启饰品，指向优先
#showtooltip [mod]14;[@mouseover,harm,nodead][]奥术飞弹
/use [mod]14
/startattack
/施放 [@mouseover,harm,nodead,nochanneling:奥术飞弹][nochanneling:奥术飞弹]奥术飞弹

满级暴风雪同时开启饰品，不打断满级引导；按shtft鼠标指向位置1级雪>按ctrl或alt鼠标瞄准>鼠标指向位置
*标题加入技能名字，用于防止因引导加入了防打断在引导中图标会变成问号的情况
#showtooltip [mod:shift]暴风雪(等级 1);暴风雪
/use [nomod:shift]14
/startattack
/施放 [mod:shift,@cursor]暴风雪(等级 1);[mod][@cursor,nochanneling:暴风雪]暴风雪

烈焰风暴同时开启饰品；组合键鼠标瞄准>鼠标指向位置
#showtooltip 烈焰风暴
/use 14
/startattack
/施放 [mod] [@cursor] 烈焰风暴

满级魔爆术同时开启饰品，组合键1级抓潜行
#showtooltip [mod]魔爆术(等级 1);魔爆术
/use [nomod]14
/startattack
/施放 [mod]魔爆术(等级 1);魔爆术

制造宝石
#showtooltip
/施放 [mod]制造魔法黄水晶;制造魔法红宝石
吃宝石
#showtooltip
/施放 [mod]法力黄水晶;法力红宝石

反制优先指向，打断施法
#showtooltip
/startattack
/stopcasting
/施放 [@mouseover,harm,nodead][]法术反制

变羊优先指向，打断施法
#showtooltip
/startattack
/stopcasting
/施放 [@mouseover,harm,nodead][]变形术

闪现，取消冰箱同时闪现，同时自动攻击偷一棍
#showtooltip
/cancelaura 寒冰屏障
/startattack
/施放闪现术

冰箱，按组合键取消冰箱；加入停止施法打断读条；加入“！”防止连点取消
*圣盾术冰箱需要立即施放的技能都应该加入“/stopcasting”停止施法
*冰箱有1.5秒连点保护时间，1.5秒之后复按会取消冰箱，添加“！”关闭取消功能
#showtooltip
/startattack
/stopcasting
/cancelaura [mod]寒冰屏障
/施放 !寒冰屏障

按组合键对自己解诅咒>指向友方>目标友方>目标的目标友方>无条件施放
#showtooltip
/施放 [mod,@player][@mouseover,help,nodead][help][@targettarget,help,nodead][]解除次级诅咒

智能宝石宏：脱战按强弱制造三种宝石，战斗按强弱吃三种宝石
*这是个LUA语言脚本宏，解决了法师三颗宝石的制造和使用的特殊情况；常规受限于字符或规则的逻辑关系需要用到脚本
*宏名字要命名为“宝石”，也可以修改“/脚本”这一行里的“宝石”2字为自己想要的标题名字即可生效
/施放 [combat][mod:alt]法力红宝石
/施放 [combat]法力黄水晶
/施放 [combat]法力翡翠
/脚本 local b,k="宝石","魔".."法" for _,x in ipairs({"红宝石","黄水晶","翡翠"})do if GetItemCount("法力"..x)==0 then EditMacro(b,nil,nil,GetMacroBody(b):gsub(k..".+",k..x))break end end
/施放 [nocombat]制造魔法红宝石
来源：[https://nga.178.com/read.php?&tid=19418985 https://nga.178.com/read.php?&tid=19418985]

小德，解中毒1 战复2 缠绕3，解诅咒1 休眠3 安抚3

术士境界，人宠合一，掌控节奏

队列灾难一条龙，5秒闲置或切目标重置，组合键同时饰品+强化诅咒，顺序习惯自行修改
#showtooltip
/use [mod]13
/施放 [mod]诅咒增幅
/startattack
/castsequence reset=5/target 献祭,痛苦诅咒,腐蚀术,生命虹吸

诅咒一条龙，5秒闲置或切目标重置，抵抗后组合键补上
#showtooltip
/startattack
/施放 [mod]元素诅咒
/castsequence reset=5/target 元素诅咒,腐蚀术,献祭

宠物特殊技能三合一；改个喜欢的图标
#showtooltip
/startattack
/petattack [@mouseover,harm,nodead];
/施放 [@mouseover,harm,nodead][]法术封锁
/施放 [@mouseover,harm,nodead][]诱惑
/施放 [@mouseover,harm,nodead][]!射击
/施放牺牲

满级火焰之雨同时开启饰品，不打断满级引导；按shift鼠标指向位置1级雨抓潜行>按ctrl或alt鼠标瞄准>鼠标指向位置
*加入施放满级开启饰品
#showtooltip [mod:shift]火焰之雨(等级 1);火焰之雨
/use [nomod:shift]14
/startattack
/施放 [mod:shift,@cursor]火焰之雨(等级 1);[mod][@cursor,nochanneling:火焰之雨]火焰之雨

满级地狱烈焰同时开启饰品，不打断满级引导；按组合键施放1级抓潜行
*加入施放
#showtooltip [mod]地狱烈焰(等级 1);地狱烈焰
/use [nomod]14
/startattack
/施放 [mod]地狱烈焰(等级 1);[nochanneling:地狱烈焰]地狱烈焰

死亡缠绕同时开启饰品，指向优先
#showtooltip [@mouseover,harm,nodead][]死亡缠绕
/use 14
/startattack
/施放 [@mouseover,harm,nodead][]死亡缠绕

暗影箭等常规技能，组合键同时开启饰品，指向优先，宝宝攻击
#showtooltip
/use [mod]14
/startattack
/petattack [@mouseover,harm,nodead];
/施放 [@mouseover,harm,nodead][]暗影箭

术士技能比较多可以把11个跟宠物有关的技能整合为4个技能，还可以加入alt组合键整合为3个技能，思路为根据BUFF常驻、应急、常规三类，可按照类型优先顺序自行组合
1.指向地狱火，shift召胖子，ctrl召小鬼
#showtooltip
/startattack
/施放 [mod:shift]召唤虚空行者;[mod:ctrl]召唤小鬼; [@cursor] 地狱火

2.恶魔支配，shift召狗，ctrl召女
#showtooltip
/startattack
/施放 [mod:ctrl]召唤魅魔;[mod:shift]召唤地狱猎犬;恶魔支配

3.魔甲，shift连接，ctrl牺牲
#showtooltip
/startattack
/施放 [mod:shift]灵魂连接;[mod:ctrl]恶魔牺牲;魔甲术

4.输血，mod吞噬
#showtooltip [mod]吞噬暗影;生命通道
/startattack
/施放 [mod]吞噬暗影;[nochanneling:生命通道]生命通道

组合键切换饰品+智能施放
#showtooltip
/eq [mod:alt]地精起搏器XL型;[mod:ctrl]灵巧秒表;[mod]第三个饰品
/use [@mouseover,exists] [@cursor] []13
*注意：怀旧服装备栏位数字编号使用物品需要用/use，直接用物品名字才可以用/施放

道具/饰品万用宏，手雷(地板类道具)或饰品指向位置或目标优先，再次按打断手雷施法在新的位置重新施放，宠物跟随，停止攻击，取消形态(暗牧删除取消形态/cancelform)
*读条的情况只适合手雷，因为有打断命令是为了让手雷重新选位置，其他读条技能可能会因为连按导致打断；饰品和其他道具几乎不会读条，适应万用放心食用
#showtooltip
/petfollow
/startattack
/stopattack
/cancelform
/stopcasting
/施放 [@mouseover,exists,nodead] [@cursor] []铁皮手雷

地板技能一键施法：按shtft脚下>按ctrl或alt鼠标瞄准后点击>鼠标瞄点位置(地板类技能通用，烈焰风暴，冰火箭雨，照明弹)
*不适用于手雷(地板类道具)，因为没有打断施法重新在新位置施放的功能，但适合其他读条或引导地板技能避免被连按打断
#showtooltip
/startattack
/施放 [mod:shift,@player][mod] [@cursor] 烈焰风暴
或取消shift对脚下，感觉没什么用
/施放 [mod] [@cursor] 烈焰风暴

急救整合解放栏位，一些绷带药剂自行添加
#showtooltip
/施放 [mod:alt]滋补药剂;[mod:ctrl]自由行动药水;[mod]有限无敌药水;[@mouseover,help,nodead][]厚符文布绷带

全职业版，指定添加取消小德形态，避免用“/cancelform”取消所有形影响到牧师暗影形态
#showtooltip
/cancelaura 巨熊形态
/cancelaura 猎豹形态
/cancelaura 旅行形态
/cancelaura 水栖形态
/施放 [mod:alt]滋补药剂;[mod:ctrl]自由行动药水;[mod]有限无敌药水;[@mouseover,help,nodead][]厚符文布绷带

各职业整合宏：组合键适用整合频率不高的非反应类型技能道具，通常shift,alt比ctrl好按一些，自己有设置组合键习惯的可以去掉相应的按键避免冲突，盗贼4种毒左右键点击八合一，能起到整合作用又不影响操作情况就算二合一也有意义

作为思维扩展包含很多各职业各种族延伸功能，一点思路请自行调节，不需要的功能请自行加减

宏能实现30个以上的功能整合在一个键位吗？受限于255字符可以用宏扩展插件突破，但这样做违背宏简化操作的根本，也无法监视图标的状态：3个组合键+正常键，姿态，敌我，死亡，战斗，环境等判定以4的倍数扩展，3个组合键+正常键的左右键分别点击，已经突破30个技能判定了。做宏要打牢基础，不忘初衷，千万不要掉入华而不实的陷阱，思维可以延伸，但要切合实际

上毒药四合一，默认主手右键副手
#showtooltip
/施放 [mod:alt]致命药膏; [mod:ctrl]麻痹毒药;[mod]致残毒药;速效毒药
/use [button:1]16; [button:2]17

磨刀涂油四合一，默认主手右键副手
#showtooltip
/施放 [mod:alt]致密平衡石;[mod:ctrl]卓越巫师之油;[mod]元素磨刀石;致密磨刀石
/use [button:1]16; [button:2]17

法师BUFF四合一
#showtooltip
/施放 [mod:alt]魔甲术;[mod:ctrl]奥术光辉;[mod]奥术智慧;冰甲术

传送三合一
#showtooltip
/施放 [mod:alt]传送：暴风城;[mod]传送：达纳苏斯;传送：铁炉堡

专业四合一
#showtooltip
/施放 [mod:alt]烹饪;[mod:ctrl]急救;[mod]工程学;炼金术

*食物推荐奥特兰克魔法点心30秒双回4410(最高回血食物)；奥特兰克泉水30秒回蓝4410精神10持续10分钟

吃喝用上药五合一；整合取消形态，影遁，潜行，宝宝潜行
#showtooltip
/cancelform
/施放 [mod:alt]用道具;[mod:ctrl]吃烹饪;[mod]XX技能;[combat]特效治疗药水;奥特兰克魔法点心
/stopmacro [mod:alt/shift]
/施放 [combat]特效治疗石
/施放魔法晶水(备选)
/施放影遁
/施放潜行
/施放 !潜伏

全职业版(除暗牧)，其他功能同上，加入鼠标指向上BUFF，鼠标右键吃蓝药，取消寒冰屏障
#showtooltip
/cancelform
/cancelaura 寒冰屏障
/施放 [mod:ctrl]吃烹饪;[mod:shift,@mouseover,help,nodead][mod:shift]XX技能;[button:2]特效治疗药水;[combat]特效治疗药水;奥特兰克魔法点心
/stopmacro [mod:shift][button:2]
/施放 [combat]特效治疗石
/施放魔法晶水(备选)
/施放影遁
/施放潜行
/施放 !潜伏

其他职业，取消多余命令，BUFF栏位改专属或功能
盗贼版(BUFF位改毒药界面)
#showtooltip
/施放 [mod:ctrl]吃烹饪;[mod:shift]毒药;[combat]特效治疗药水;奥特兰克魔法点心
/stopmacro [mod:shift]
/施放 [combat]特效治疗石
/施放影遁
/施放潜行

暗牧版(不取消形态)
#showtooltip
/施放 [mod:ctrl]吃烹饪;[mod:shift,@mouseover,help,nodead][mod:shift]XX技能;[button:2]XX法力药水;[combat]特效治疗药水;奥特兰克魔法点心
/stopmacro [mod:shift][button:2]
/施放 [combat]特效治疗石
/施放魔法晶水(备选)
/施放影遁

战士版(加入战斗中破斧，shift主手魔刀，shift+右键副手磨刀)
#showtooltip
/施放 [combat]破釜沉舟
/施放 [mod:ctrl]奥特兰克魔法点心;[mod:shift]致密磨刀石;[combat]特效治疗药水;魔法甜面包
/use [button:1]16; [button:2]17
/stopmacro [mod:shift]
/施放 [combat]特效治疗石
/施放影遁

全职业(除暗牧)上坐骑整合宏：同时起立，下马，停止攻击，宝宝跟随，宠物潜行；组合键种族技能
小德额外功能：战斗取消变形同时变水栖或旅行，秒切姿态解定身减速；
按ctrl或alt取消形态同时影遁，按shift取消形态变形旅行形态，用于脱战短距离旅行
*加入骑术召唤坐骑在最下面是为备用，在下坐骑后有3秒CD这时候可以使用没CD的职业坐骑
#showtooltip
/stand
/dismount
/petfollow
/stopattack
/cancelform
/施放 [nomod,nocombat]精龙的蛋(需要小动物添加这一行在坐骑前面，小德添加在取消形态下面变形前面)
/施放 [swimming]水栖形态;[mod:shift][combat]旅行形态
/施放 [mod]感知;黑马缰绳
/施放 [mod]!影遁;条纹霜刃豹缰绳
/施放 [mod]!潜伏
/施放召唤地狱战马
/施放召唤军马

单职业的话在上面基础上修改，小德和暗牧形态冲突不能共存需单独做一个
小德：取消形态同时变水栖或旅行，秒切姿态解定身减速；
按ctrl取消形态同时影遁，按shift或alt取消形态同时上坐骑
#showtooltip
/stand
/dismount
/cancelform
/施放 [mod:ctrl]!影遁;[mod]条纹霜刃豹缰绳;[swimming]水栖形态;旅行形态

暗牧：去掉取消形态
#showtooltip
/stand
/dismount
/stopattack
/施放 [mod]!影遁;条纹霜刃豹缰绳
/施放 [mod]感知;黑马缰绳

下面是我在用的，按种族分类，小德独立一类，有小宠物和变形魔棒玩具，自行加减；和种族混合宏的区别是按组合键能看到第二排的种族技能CD

人类
*加入骑术召唤坐骑在最下面是为备用，在下坐骑后有3秒CD这时候可以使用没CD的职业坐骑
#showtooltip
/stand
/dismount
/petfollow
/stopattack
/施放 [nomod,nocombat]精龙的蛋
/施放 [mod:ctrl]达图尔的变形魔棒;[mod]感知;迅捷霜刃豹缰绳
/施放召唤军马
/施放召唤地狱战马

暗夜
#showtooltip
/stand
/dismount
/petfollow
/stopattack
/施放 [nomod,nocombat]精龙的蛋
/施放 [mod:ctrl]达图尔的变形魔棒;[mod]!影遁;迅捷霜刃豹缰绳
/施放 [mod]!潜伏

小德
*因为小宠物需要写在前面，但这样会影响显示图标，所以把条件写在显示图标标题上这样就解决显示问题
#showtooltip [mod:ctrl]!影遁;[mod]条纹霜刃豹缰绳;[swimming]水栖形态;旅行形态
/stand
/dismount
/cancelform
/施放 [nomod,nocombat]精龙的蛋
/施放 [mod:ctrl]!影遁;[mod]迅捷霜刃豹缰绳;[swimming]水栖形态;旅行形态

全职业取消宏
/cancelform
/cancelaura 降落伞
/cancelaura 魔法抑制
/cancelaura 魔法增效
/cancelaura 法力护盾
/cancelaura 寒冰屏障
/cancelaura 拯救祝福
/cancelaura 强效拯救祝福
/cancelaura 保护祝福
/cancelaura 牺牲祝福
/cancelaura 圣盾术
/cancelaura 潜行
/cancelaura 血性狂暴
/cancelaura 真言术：盾
/cancelaura 熊怪形态

找怪宏并标记骷髅(1-60大部分任务怪)
/目标迈雷
/目标萨丝
/目标安娜
/目标老瞎
/目标邪恶
/目标摩拉
/目标列兵
/目标辛达
/目标纳兹
/目标巴尔
/目标考格
/目标马格
/目标格林
/目标老海
/目标泰希
/目标木棒
/目标卡利
/目标断牙
/目标图加
/目标赫拉
/目标喋喋
/目标游荡
/目标生病
/目标守财
/目标弗雷
/脚本 SR=SetRaidTarget;TG="target"
/脚本 SR(TG,8)

一键标记宏(数字改人名)
/脚本 SR=SetRaidTarget;TG="target"
/cleartarget
/目标 1
/脚本 SR(TG,1)
/cleartarget
/目标2
/脚本 SR(TG,2)
/cleartarget
/目标3
/脚本 SR(TG,3)
/cleartarget
/目标4
/脚本 SR(TG,4)
/cleartarget
/目标5
/脚本 SR(TG,5)

自动喊话宏，先按第一个宏，再按第二个宏即可按设定时间重复
内容出复写喊话内容
/脚本 ps="内容";sc=SendChatMessage;

时间处复写重复时间秒数，频道处复写频道数字比如/1 就复写1
/脚本 T,F=T or 0,F or CreateFrame("frame")if X then print("off") X=nil else print("on") X=function()local t=GetTime()if t-T>时间 then SendChatMessage(ps,"channel",nil,频道)T=t end end end F:SetScript("OnUpdate",X)

防止掉线挂机
/script T,F=0,CreateFrame("frame")if X then X=nil else X=function()local t=GetTime()StaticPopup1Button1:Click()if t-T>0.2 then AcceptGroup()T=t end if UnitIsGroupLeader("player")then LeaveParty()end end end F:SetScript("OnUpdate",X)

TBC补充
TBC加入焦点功能，所有宏可以在施放条件前端加入[mod,@focus,harm]按组合键对焦点目标施法的条件，在原来的宏基础上加入即可，需求焦点功能的宏都可以添加；例子如下
/施放 [mod,@focus,harm][@mouseover,harm,nodead][]技能
目标身份判定按需求修改harm敌人，help友方，exists存在

TBC补充
战士
加入援护的三合一，判定状态一键切姿态放技能
#showtooltip [@mouseover,help] 援护;[mod][combat,@mouseover,harm][combat]拦截; [@mouseover,harm] []冲锋
/施放 [@mouseover,help] 防御姿态;[mod][combat]狂暴姿态;战斗姿态
/startattack
/施放 [@mouseover,help] 援护;[mod][combat,@mouseover,harm][combat]拦截; [@mouseover,harm] []冲锋

TBC补充
法师
/petfollow 宝宝跟随，对于法师绑定到羊上，虽然羊好的目标宝宝会自动停手但不会在读条时就停手，所以羊时需要同时有这个命令停手；例子如下
组合键焦点羊>指向羊>目标羊，同时宝宝跟随
#showtooltip [mod,@focus,harm][@mouseover,harm,nodead][]变形术
/startattack
/petfollow
/施放 [mod,@focus,harm][@mouseover,harm,nodead][]变形术

/petattack [@mouseover,harm,nodead]; 宝宝攻击优先指向，一般绑定到主攻单体持续输出的技能上；例子如下
组合键1级寒冰剑>指向寒冰箭>目标寒冰箭
#showtooltip [mod,@mouseover,harm,nodead][mod]寒冰箭(等级 1);[@mouseover,harm,nodead][]寒冰箭
/startattack
/petattack [@mouseover,harm,nodead];
/施放 [mod,@mouseover,harm,nodead][mod]寒冰箭(等级 1);[@mouseover,harm,nodead][]寒冰箭

无宝宝召唤宝宝，有宝宝冰冻术
*宝宝的地板技能冰冻术无法用 [@cursor] 指向施法，需要点击施法
#showtooltip
/施放 [nopet]召唤水元素;冰冻术

六门合一(组合键是不是不够用了，对于这种低频率闲时施放技能完全可以加入右键点击，这是个思路，按这个思路可以进行超拓展)
#showtooltip
/施放 [mod:alt,button:2]传送门：雷霆崖;[mod:alt]传送门：沙塔斯;[mod:ctrl]传送门：银月城;[mod]传送门：幽暗城;[button:2]传送门：斯通纳德;传送门：奥格瑞玛
八合一超拓展(传送门虽然是极端但WLK加入达拉然也只需要六合一，八合一只是举例实际上没有东西需要用到，也不建议无关的技能加入)
/施放 [mod:alt,button:2]传送门：达拉然;[mod:ctrl,button:2]传送门：沙塔斯;[mod:mod,button:2]传送门：暴风城;[mod:alt]传送门：幽暗城;[mod:ctrl]传送门：雷霆崖;[mod]传送门：银月城;[button:2]传送门：斯通纳德;传送门：奥格瑞玛

三甲合一
#showtooltip
/施放 [mod:ctrl]熔岩护甲;[mod:shift]法师护甲;冰甲术

满级暴风雪不打断，shift组合键一级雪，其他组合键显示满级雪鼠标指示器施法
*偶尔需要一级雪控场的组合
#showtooltip [mod:shift]暴风雪(等级 1);暴风雪
/startattack
/use [nomod:shift,nochanneling:暴风雪]14
/施放 [nomod:shift,nochanneling:暴风雪]冰冷血脉
/施放 [mod:shift,@cursor]暴风雪(等级 1);[mod][@cursor,nochanneling:暴风雪]暴风雪
/petattack [@mouseover,harm,nodead];

一级暴风雪，shift组合键烈焰风暴，其他组合键显示烈焰风暴鼠标指示器施法
*刷本专用，避免频繁使用组合键一级雪的繁琐
#showtooltip [mod:shift][mod]烈焰风暴;暴风雪(等级 1)
/startattack
/use [mod]14
/施放 [mod]冰冷血脉
/施放 [mod:shift,@cursor][mod]烈焰风暴; [@cursor] 暴风雪(等级 1)
/petattack [@mouseover,harm,nodead];

常规读条输出技能，整合宝宝攻击命令优先指向，不打断暴风雪引导
#showtooltip [@mouseover,harm,nodead][]寒冰箭
/startattack
/use [nochanneling:暴风雪]14
/施放 [nochanneling:暴风雪]冰冷血脉
/施放 [mod,@mouseover,harm,nodead][mod]寒冰箭(等级 1);[@mouseover,harm,nodead,nochanneling:暴风雪][nochanneling:暴风雪]寒冰箭
/petattack [@mouseover,harm,nodead];